*Converte a lista do radio50 para o formato usado no radiovox;
*Por Fabiano Ferreira;
*Em 06/05/2023;

Escreve "Converte listas do Radio50 para listas do Radiovox"
escreve ""

@qualnomearquivo
Escreve "Qual o nome do arquivo lista do radio50?"
le a
se a = ""
escreve "Desistiu"
termina mudo
fim se

busca b a
se b = ""
escreve "Arquivo não encontrado"
Escreve "Verifique o nome informado e tente novamente."
desvia @qualnomearquivo
fim se

Escreve "Gerando listas, aguarde"
seja $listas_geradas 0
abre #1 a
le #1 l
checa c
enquanto c = 0
se l =* "["
 chama @extrairadios
fim se
le #1 l
checa c
fim enquanto

Escreve "Terminado!"
Escreve $listas_geradas" listas geradas"
escreve ""
escreve "Aperte enter"
le
termina mudo

@extrairadios
soma $listas_geradas 1
seja p pos "[" l
soma p 1
seja t tamanho l
subtrai t 1
copia l l p t
seja $nomelista $listas_geradas
seja $zero ""
seja t tamanho $nomelista
se t < 3
seja x (3-t)
repete r x
concatena $zero "0"
fim repete
fim se
concatena $zero $nomelista
seja $nomelista $zero
concatena $nomelista " - "
seja l maiusc l
concatena $nomelista l
abre #2 $nomelista &
le #1 l
checa c
enquanto c = 0
se não l =* "["
chama @extrainomeradio
chama @extrailinkradio
escreve #2 $nomeradio
escreve #2 $linkradio
senão
fecha #2
desvia @extrairadios
fim se
le #1 l
checa c
fim enquanto
retorna

@extrainomeradio
seja $nomeradio ""
seja p pos "="l
subtrai p 1
copia x l 1 p
seja $nomeradio x
soma p 2
seja t tamanho l
copia l l p t
retorna

@extrailinkradio
seja $linkradio l
retorna
